電書ちょこっとツールズ

スクリーン連続キャプチャ for OSX

デスクトップをキャプチャして、切り抜き、リサイズをしてpngに保存するAppleScriptです。 左右のカーソルキーを押しつつ、連続で連番のpngにすることができます。

各種パラメータは、スクリプトの頭で定義されているので、適宜変更して使ってください。

-- ページ数
set pages to 2
-- 対象アプリ
set target to "iBooks"
-- 保存フォルダ
set savepath to "~/Pictures/"
-- 開始ファイル番号
set spage to 1
-- めくり方向(1=左 2=右)
set pagedir to 1
-- ページめくりウエイト(秒)
set pausetime to 2.0
-- 切り抜きサイズ(画面中心から)
set cropx to 0
set cropy to 0
-- リサイズ横(切り抜く前のサイズ換算=画面横/切り抜き横*仕上がり横)
set resizew to 0


if pagedir = 1 then
	set keychar to (ASCII character 28)
else
	set keychar to (ASCII character 29)
end if
if target is not "" then
	tell application target
		activate
	end tell
end if
delay pausetime
repeat with i from spage to pages
	if i < 10 then
		set dp to "00" & i
	else if i < 100 then
		set dp to "0" & i
	end if
	set spath to (savepath & "p" & dp & ".png")
	do shell script "screencapture   " & spath
	if cropx is not 0 and cropy is not 0 then
		if resizew is not 0 then
			do shell script "sips -c " & cropy & " " & cropx & " --resampleWidth " & resizew & " " & spath & " --out " & spath
		else
			do shell script "sips -c " & cropy & " " & cropx & " " & spath & " --out " & spath
		end if
	end if
	tell application "System Events"
		keystroke keychar
	end tell
	delay pausetime
end repeat
activate

• 対象アプリ名を設定すると、そのアプリをアクティブにしてからキャプチャを始めます。うまく切り替わらない場合は、ここは空白にして、スクリプト実行後に手動でウインドウを切り替えてください。
• 対象アプリは全画面化しておくと、余計なものをキャプチャしないので便利です。
• 保存されたpngは、プレビューでまとめて開いて、印刷するかPDFとして保存するとなにかと便利です。

スクリプトダウンロード : pagecapture.scpt
ダウンロードしてファイルを起動すると、Applescripteエディタが起動するので、パラメータを変更の上実行してください。

Tweet